Celestin Apprentice 2/Apprentice-Release2.iso/Source Code/Peter Lewis/PNL Libraries/MyAEGetData.p

Text File | 1994-02-04 | 2.8 KB | 93 lines | [TEXT/PJMM]

unit MyAEGetData;

interface

    procedure InitAEGetData (GetSelectionProc: ProcPtr);
{ function GetSelectionProc(var reply:AppleEvent):OSErr; }
    procedure FinishAEGetData;

implementation

    uses
        AERegistry, AEObjects;

    const
        MaxPropLevel = 2; { or whatever number of levels you want to support }

    type
        propArray = array[1..MaxPropLevel] of DescType;

    function CallGetSelection (var reply: AppleEvent; proc: ProcPtr): OSErr;
    inline
        $205F, $4E90;

    var
        getdata: ProcPtr;

    function PropertyOf (theSpec: AERecord; var propLevel: integer; var properties: propArray): boolean;
        var
            objSpec: AERecord;
            typ, t, prop: DescType;
            size: longint;
            key: AEKeyword;
            err: OSErr;
    begin
        PropertyOf := false; { we don't know this is a property yet }
        if propLevel = 0 then begin { 0 means the Apple Event }
            key := keyDirectObject;
        end
        else begin
            key := keyAEContainer;
        end;
        if AEGetKeyDesc(theSpec, key, typeAERecord, objSpec) = noErr then begin
            if (AEGetKeyPtr(objSpec, keyAEDesiredClass, typeType, typ, @t, 4, size) = noErr) & (t = cProperty) then begin
                if (AEGetKeyPtr(objSpec, keyAEKeyForm, typeEnumerated, typ, @t, 4, size) = NoErr) & (t = formPropertyID) then begin { this is redundunt, won't hurt to make sure }
                    if AEGetKeyPtr(objSpec, keyAEKeyData, typeType, typ, @prop, 4, size) = NoErr then begin { which of property? }
                        propLevel := propLevel + 1;
                        properties[propLevel] := prop;
                        if AESizeOfKeyDesc(objSpec, keyAEContainer, typ, size) = NoErr then begin { property of what }
                            if typ = typeNull then begin { prop of application, we are done }
                                PropertyOf := true;
                            end
                            else if typ = typeObjectSpecifier then begin { from another object specifer }
                                if propLevel < MaxPropLevel then { only do it if we have not reach max level }
                                    PropertyOf := PropertyOf(objSpec, propLevel, properties); { go down 1 level }
                            end; { else it is an error }
                        end;
                    end;
                end;
            end;
            err := AEDisposeDesc(objSpec);
        end;
    end;

    function MyGetDataHandler (event, reply: AppleEvent; theRefcon: longint): OSErr;
        var
            err: OSErr;
            propLevel: integer;
            properties: propArray;
    begin
        err := errAENoSuchObject;
        propLevel := 0; { 0 means we are passing in an Apple Event }
        if PropertyOf(event, propLevel, properties) & (propLevel = 2) then begin
            if (properties[1] = pContents) & (properties[2] = pSelection) then begin { it is content of selection }
                err := CallGetSelection(reply, getdata);
{ do your thing and put the result in the reply }
            end;
        end;
        MyGetDataHandler := err;
    end;

    procedure InitAEGetData (GetSelectionProc: ProcPtr);
        var
            junk: OSErr;
    begin
        getdata := GetSelectionProc;
        junk := AEInstallEventHandler(kAECoreSuite, kAEGetData, @MyGetDataHandler, 0, false);
    end;

    procedure FinishAEGetData;
    begin
    end;

end.